1 files changed, 85 insertions, 0 deletions
diff --git a/profiles/dev.nix b/profiles/dev.nix
new file mode 100644
index 0000000..e20fe5a
--- /dev/null
+++ b/profiles/dev.nix
@@ -0,0 +1,85 @@
+# Dev profile: compilers, language servers, dev CLIs, and Emacs. Opt-in per machine.
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    zig
+    prettier
+
+    (aspellWithDicts (
+      dicts: with dicts; [
+        en
+        en-computers
+        en-science
+      ]
+    ))
+
+    pi-coding-agent
+
+    (buildNpmPackage rec {
+      pname = "pi-acp";
+      version = "0.0.31";
+      src = fetchFromGitHub {
+        owner = "svkozak";
+        repo = "pi-acp";
+        rev = "v${version}";
+        hash = "sha256-bM3V/3fxkY2Ib+OyfT82StIIRSLXGDuYUbt1CZKpTuo=";
+      };
+      npmDepsHash = "sha256-qN+b/tMbnJLkWjotl3XrA0nfZ3KT/mT6gM+n3Qiz8Wk=";
+    })
+  ];
+
+  users.users.henz.packages = with pkgs; [
+    # toolchains / build
+    gcc
+    pkg-config
+    gnumake
+    autoconf
+    automake
+    libtool
+    cargo
+    nodejs
+    guile
+    direnv
+    gdb
+
+    # language servers / formatters
+    lua-language-server
+    nil
+    clang-tools
+    marksman
+    gopls
+    ruff
+    basedpyright
+    zls
+    nixfmt
+
+    # coding agents
+    opencode
+    claude-code
+  ];
+
+  services.emacs = {
+    enable = true;
+    package =
+      let
+        emacs = pkgs.emacs-pgtk.overrideAttrs (old: {
+          postInstall = (old.postInstall or "") + ''
+            # I only want the client version
+            rm -f $out/share/applications/emacs.desktop
+          '';
+        });
+      in
+      (pkgs.emacsPackagesFor emacs).withPackages (epkgs: [
+        # NB: no g.tree-sitter-zig -- nixpkgs builds it from maxxnino/tree-sitter-zig,
+        # but zig-ts-mode requires the tree-sitter-grammars/tree-sitter-zig variant
+        # (different node names).  The zig grammar is installed instead via
+        # `C-u M-x zig-ts-install-grammars' into ~/.config/emacs/tree-sitter/.
+        (epkgs.treesit-grammars.with-grammars (g: [
+          g.tree-sitter-nix
+          g.tree-sitter-javascript
+        ]))
+        epkgs.vterm
+      ]);
+  };
+}