From 974a2ba37bfb80934275adc335e8f0a0ffcf49a3 Mon Sep 17 00:00:00 2001
From: Henry Webster <hwebs@hwebs.info>
Date: Wed, 22 Jul 2026 22:28:24 -0500
Subject: initial commit

---
 overlays/haunt.nix | 26 ++++++++++++++++++++++++++
 1 file changed, 26 insertions(+)
 create mode 100644 overlays/haunt.nix

(limited to 'overlays')

diff --git a/overlays/haunt.nix b/overlays/haunt.nix
new file mode 100644
index 0000000..cae6a0a
--- /dev/null
+++ b/overlays/haunt.nix
@@ -0,0 +1,26 @@
+final: prev: {
+  # haunt 0.4.0 needs the (commonmark html) module, which the pinned
+  # OrangeShark guile-commonmark (unstable-2020-04-30) doesn't provide.
+  # Track the Spritely fork that Guix now uses.
+  guile-commonmark = prev.guile-commonmark.overrideAttrs (finalAttrs: old: {
+    version = "0.1.2-unstable-2024";
+    src = final.fetchgit {
+      url = "https://codeberg.org/spritely/guile-commonmark";
+      rev = "8ebb3041973ee65eed71757c97d09c63b842ac9a";
+      hash = "sha256-YYMBUDpRHwscuGv3LieYWHUlOJRJpaK39nLKlpl+ZVE=";
+    };
+  });
+
+  haunt = prev.haunt.overrideAttrs (finalAttrs: old: {
+    version = "0.4.0";
+    src = final.fetchgit {
+      url = "https://git.dthompson.us/haunt.git";
+      tag = "v${finalAttrs.version}";
+      hash = "sha256-VRs70ETGB/ygr0HUW5mfGxaLKex0VPbX4r8HCIxV3K0=";
+    };
+    # 0.4.0 adds a dependency on the (htmlprag) Guile module from guile-lib.
+    # guile-gnutls provides the (gnutls) module that (web client) needs for
+    # HTTPS, so build-time fetching of remote pages works.
+    buildInputs = old.buildInputs ++ [ final.guile-lib final.guile-gnutls ];
+  });
+}
-- 
cgit v1.3