{ pkgs, ... }:

let
  # open the MusicBrainz submission URL for the disc in the drive
  discid = pkgs.writeShellApplication {
    name = "discid";
    runtimeInputs = [
      pkgs.discidurl
      pkgs.xdg-utils
    ];
    text = "discidurl | xargs -r xdg-open";
  };
in
{
  environment.systemPackages = with pkgs; [
    discidurl
    discid

    itch
    haunt

    # --- wayland
    mako

    # provides notify-send
    libnotify

    # website is down :(
    # makemkv

    (aspellWithDicts (
      dicts: with dicts; [
        en
        en-computers
        en-science
      ]
    ))

    pi-coding-agent

    (buildNpmPackage rec {
      pname = "pi-acp";
      version = "0.0.31";
      src = fetchFromGitHub {
        owner = "svkozak";
        repo = "pi-acp";
        rev = "v${version}";
        hash = "sha256-bM3V/3fxkY2Ib+OyfT82StIIRSLXGDuYUbt1CZKpTuo=";
      };
      npmDepsHash = "sha256-qN+b/tMbnJLkWjotl3XrA0nfZ3KT/mT6gM+n3Qiz8Wk=";
    })

  ];

  programs = {
    steam.enable = true;
    firefox.enable = true;

    gnupg.agent = {
      enable = true;
      enableSSHSupport = true;
    };
  };

  services = {
    emacs = {
      enable = true;
      package =
        let
          emacs = pkgs.emacs-pgtk.overrideAttrs (old: {
            postInstall = (old.postInstall or "") + ''
              # I only want the client version
              rm -f $out/share/applications/emacs.desktop
            '';
          });
        in
        (pkgs.emacsPackagesFor emacs).withPackages (epkgs: [
          (epkgs.treesit-grammars.with-grammars (g: [ g.tree-sitter-nix ]))
          epkgs.vterm
        ]);
    };

    ollama = {
      enable = true;
      package = pkgs.ollama-rocm;
      environmentVariables = {
        HIP_VISIBLE_DEVICES = "0";
        OLLAMA_CONTEXT_LENGTH = "32768";
        OLLAMA_KV_CACHE_TYPE = "q8_0";
      };
    };
  };

  services.immich = {
    enable = true;
    machine-learning.enable = false;
  };
}